Delta := ((ColorF - ColorI) SHL 9) DIV Steps;

I use two arrays for this set of two functions... One is the delta array, and the other holds the current palette. Both have 768 entries and both are composed of integers. Why didn't I just read the palette entries every time instead of saving them? If we did that, we would lose all of our fractional data that we worked so hard for! We have already covered how to initialize the delta array (Just repeat 768 times: one for each color), but how do we initialize the CurrentPalette? We simply read the current palette out of the VGA (using regs $3C7 and $3C9 remember?) and shift it left nine times.

With all of this, we can now write the PalFadeContinue function. All it has to do is decrement step (If zero, quit with a TRUE), add all of Delta to Cur (the current palette), and output Cur SHR 9 to the palette registers. This would look something like this:

FUNCTION PalFadeContinue : BOOLEAN;
VAR I : INTEGER;
BEGIN
  IF Step = 0 THEN
  BEGIN
    PalFadeContinue := TRUE;
    EXIT;
  END;
  Port[$3C8] := 0;
  FOR I := 0 TO 767 DO
  BEGIN
    Cur[I] := Cur[I] + Delta[I];
    Port[$3C9] := Cur[I] SHR 9;
  END;

  PalFadeContinue := FALSE;
END;

I use these routines with my Timer unit the most. This makes sure that the palette fades smoothly and constantly (And it looks the same on all computers). Check out: Particle for an example...

PROCEDURE LoadPal(Filename : STRING; Pal : PalArrayPtr);
VAR F : FILE;
BEGIN
  ASSIGN(F, Filename);
  RESET(F, 3);
  BlockRead(F, Pal^, FileSize(F));
  CLOSE(F);
END;

PROGRAM PaletteExample;
USES
  GraphPro, { InitGraph, CloseGraph, VLine }
  Palette,  { Lots of functions...         }
  CRT;      { Uses KeyPressed & ReadKey    }

VAR
  NewPal, BlackPal : PalArrayPtr;
  I, J : INTEGER;
BEGIN
  InitGraph;
  New(BlackPal);
  New(NewPal);
  FillChar(BlackPal^, SIZEOF(PalArrayType), 0);
  SetPalBlock(0, 256, BlackPal);

  FOR I := 0 TO 319 DO
    VLine(I, 0, 199, I AND 31);

  J := 0;
  WHILE NOT KeyPressed DO
  BEGIN
    WHILE (Port[$3DA] AND 8) = 0 DO; { Wait for vertical retrace   }
    WHILE (Port[$3DA] AND 8) = 8 DO; { Wait while vertical retrace }

    FOR I := 0 TO 15 DO
      SetPal((I+J) AND 31, I*4, I*4, 0);
    FOR I := 0 TO 15 DO
      SetPal((I+J+16) AND 31, 63-I*4, 63-I*4, 0);
    INC(J);
  END;
  ReadKey;

  StartPalFade(BlackPal, 60*1);
  FinishFade;                   { Does the same thing as FadeToBlack }

  FOR I := 0 TO 15 DO
  BEGIN
    NewPal^[I].R := I*4;
    NewPal^[I].G := I*4;
    NewPal^[I].B := I*4;
    NewPal^[I+16].R := 63-I*4;
    NewPal^[I+16].G := 63-I*4;
    NewPal^[I+16].B := 63-I*4;
  END;

  StartPalFade(NewPal, 60*2);
  FinishFade;
  FadeToWhite(1);
  FadeToBlack(0.5);

  Dispose(BlackPal);
  CloseGraph;
END.